EDU-555 Add As Task File action should be undoable and revertable
[idea/community.git] / python / educational-core / build.gradle
1 import org.apache.tools.ant.filters.ReplaceTokens
2
3 buildscript {
4   ext.kotlin_version = '1.0.3'
5   repositories {
6     mavenCentral()
7   }
8   dependencies {
9     classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
10   }
11 }
12
13 plugins {
14   id "org.jetbrains.intellij" version "0.0.43"
15 }
16
17 subprojects {
18
19   apply plugin: 'java'
20   apply plugin: 'kotlin'
21   apply plugin: "org.jetbrains.intellij"
22
23   tasks.withType(JavaCompile) { options.encoding = 'UTF-8' }
24
25   sourceSets {
26     main {
27       java.srcDir 'src'
28       kotlin.srcDirs 'src'
29       resources.srcDir 'resources'
30     }
31     test {
32       java.srcDir 'test'
33     }
34   }
35
36   intellij {
37     version ideaVersion
38     updateSinceUntilBuild Boolean.valueOf(updateBuildNumber)
39     downloadSources Boolean.valueOf(downloadIdeaSources)
40     sandboxDirectory = new File(rootProject.projectDir, "gradleBuild/idea-sandbox")
41   }
42
43   processResources {
44     filesNotMatching("**/*.png") {
45       it.filter(ReplaceTokens, tokens: [
46         'VERSION'     : version.toString(),
47         'BUILD-NUMBER': buildNumber,
48       ])
49     }
50   }
51
52   afterEvaluate {
53     tasks.getByName('buildPlugin') {
54       archiveName = "$intellij.pluginName-$version-${buildNumber}.zip"
55     }
56   }
57
58   buildDir = new File(rootProject.projectDir, "gradleBuild/" + project.name)
59 }
60
61 project(':student') {
62
63   dependencies {
64     compile fileTree(dir: 'lib', include: ['*.jar'])
65   }
66
67   intellij {
68     pluginName 'student'
69   }
70
71 }
72
73 project(':course-creator') {
74
75   dependencies {
76     compile project(':student')
77   }
78
79   intellij {
80     pluginName 'course-creator'
81   }
82
83 }