IDEA-221448 fixed set linked project path for static empty state of external storage
[idea/community.git] / build / update.cmd
1 @ECHO OFF
2
3 :: This script updates your IntelliJ IDEA CE installation from the latest compiled classes. This way you can easily
4 :: upgrade your working IDEA to the latest changes.
5 ::
6 :: Before you run the script, ensure you have the following:
7 :: 1. Your IntelliJ IDEA project is fully built (do 'Rebuild Project' if unsure).
8 :: 2. WORK_IDEA_HOME points to the directory of IntelliJ IDEA build you want to upgrade.
9 :: 3. DEV_IDEA_HOME points to the directory of the project you built at step 1.
10 :: 4. JAVA_HOME points to a valid JDK installation.
11 :: 5. You quit IntelliJ IDEA.
12
13 IF NOT EXIST "%WORK_IDEA_HOME%\bin\idea.bat" (
14   ECHO WORK_IDEA_HOME must be defined and point to IDEA installation you wish to update
15   EXIT
16 )
17
18 IF NOT EXIST "%DEV_IDEA_HOME%\build\update.cmd" (
19   ECHO DEV_IDEA_HOME must be defined and point to a source base you're updating from
20   EXIT
21 )
22
23 IF NOT EXIST "%JAVA_HOME%\bin\java.exe" (
24   ECHO JAVA_HOME must be defined and point to a valid Java installation
25   EXIT
26 )
27
28 ECHO Updating "%WORK_IDEA_HOME%" from compiled classes at "%DEV_IDEA_HOME%"
29
30 CD "%DEV_IDEA_HOME%"
31
32 SET ANT_HOME=%DEV_IDEA_HOME%\lib\ant
33 SET EXEC_ANT="%JAVA_HOME%\bin\java.exe" -Xmx512m -Dant.home="%ANT_HOME%" -classpath "%ANT_HOME%\lib\ant-launcher.jar" org.apache.tools.ant.launch.Launcher
34 %EXEC_ANT% -f build/update.xml -Dwork.idea.home="%WORK_IDEA_HOME%" -Dintellij.build.local.plugins.repository="%BUILD_LOCAL_PLUGINS_REPOSITORY%"
35 IF NOT ERRORLEVEL 0 GOTO failed
36 IF NOT EXIST "%DEV_IDEA_HOME%\out\deploy" GOTO failed
37
38 RMDIR /Q /S "%WORK_IDEA_HOME%\lib"
39 RMDIR /Q /S "%WORK_IDEA_HOME%\plugins"
40
41 XCOPY "%DEV_IDEA_HOME%\bin\win\*.dll" "%WORK_IDEA_HOME%\bin\" /Q /E /Y
42 XCOPY "%DEV_IDEA_HOME%\bin\win\*.exe" "%WORK_IDEA_HOME%\bin\" /Q /E /Y
43 XCOPY "%DEV_IDEA_HOME%\out\deploy\dist\*.*" "%WORK_IDEA_HOME%\" /Q /E /Y
44 GOTO done
45
46 :failed
47 ECHO Update failed; work IDEA build not modified
48
49 :done
50 CD /D "%WORK_IDEA_HOME%\bin"